First commit. FLMNG and DubSiren are already here
This commit is contained in:
238
FLMNG/FLMNG.ino
Normal file
238
FLMNG/FLMNG.ino
Normal file
@ -0,0 +1,238 @@
|
||||
// 2 Operator FM Synth firmware for Sitka Instruments WS-1.0
|
||||
// by Oleksiy Hrachov
|
||||
//
|
||||
// Code is partly based on Knob_LightLevel_x2_FMSynth example from Mozzi Library
|
||||
//
|
||||
// Although the code designed to work on Sitka Instruments WS-1.0 synth, it should
|
||||
// be pretty easy to adapt to run on other arduino/mozzi-based setups
|
||||
//
|
||||
// This code is licenced under GPL v3 or later
|
||||
|
||||
//ToDo:
|
||||
//test how accurate and fast oversampling is
|
||||
//smooth harmonics knob?
|
||||
//rework LFO/Intensity so when LFO rate is 0, intensidy doesn't depend on its phase
|
||||
|
||||
#include <Mozzi.h>
|
||||
#include <MIDI.h>
|
||||
#include <Oscil.h>
|
||||
#include <tables/sin2048_int8.h>
|
||||
#include <tables/square_no_alias_2048_int8.h>
|
||||
#include <tables/saw2048_int8.h>
|
||||
#include <tables/whitenoise8192_int8.h>
|
||||
#include <Smooth.h>
|
||||
#include <ADSR.h>
|
||||
#include <mozzi_midi.h>
|
||||
#include <IntMap.h>
|
||||
#include <OverSample.h>
|
||||
|
||||
//Settings
|
||||
const int pitchSubSteps = 16; //set how many steps are there between semitones. set to 1 to quantize to semitones
|
||||
const int driveAmount = 350;
|
||||
const bool oversamplingEnabled = false; //makes V/OCT tracking more precise, but adds a little portamento
|
||||
#define MIDI_CHANNEL 1 //MIDI_CHANNEL_OMNI
|
||||
#define MOZZI_CONTROL_RATE 1024
|
||||
|
||||
//Hardware Definitions
|
||||
#define Knob1 A6 //Intensity
|
||||
#define Knob2 A4 //Modulator frequency ratio/Harmonics
|
||||
#define Knob3 A2 //LFO Frequency
|
||||
#define Knob4 A0 //LFO Shape
|
||||
#define KnobA A5 //Attack
|
||||
#define KnobDR A3 //Decay and Release
|
||||
#define KnobS A1 //Sustain
|
||||
#define CVIn A7 //CV input and Pitch knob
|
||||
#define GateIn 10
|
||||
#define EnvSwitch 11
|
||||
#define DroneSwitch 12
|
||||
#define LED 5
|
||||
|
||||
#define MOZZI_ANALOG_READ_RESOLUTION 10
|
||||
|
||||
MIDI_CREATE_DEFAULT_INSTANCE();
|
||||
|
||||
IntMap kMapCarrierNote( 0, 4095, 24 * pitchSubSteps, 84 * pitchSubSteps );
|
||||
IntMap kMapIntensity( 0, 1023, 10, 350 );
|
||||
IntMap kMapHarmonics( 0, 1023, 1, 40 );
|
||||
IntMap kMapLFOSpeed( 0, 1023, 1, 10000 );
|
||||
IntMap kMapAttack( 0, 1023, 0, 80 );
|
||||
IntMap kMapDecayRelease( 0, 1023, 8, 160 );
|
||||
IntMap kMapSustain( 0, 1023, 0, 255 );
|
||||
|
||||
Oscil<SIN2048_NUM_CELLS, MOZZI_AUDIO_RATE> aCarrier(SIN2048_DATA);
|
||||
Oscil<SIN2048_NUM_CELLS, MOZZI_AUDIO_RATE> aModulator(SIN2048_DATA);
|
||||
Oscil<SIN2048_NUM_CELLS, MOZZI_CONTROL_RATE> kSineLFO(SIN2048_DATA);
|
||||
Oscil<SQUARE_NO_ALIAS_2048_NUM_CELLS, MOZZI_CONTROL_RATE> kSquareLFO(SQUARE_NO_ALIAS_2048_DATA);
|
||||
Oscil<SAW2048_NUM_CELLS, MOZZI_CONTROL_RATE> kSawLFO(SAW2048_DATA);
|
||||
Oscil<WHITENOISE8192_NUM_CELLS, MOZZI_CONTROL_RATE> kNoiseLFO(WHITENOISE8192_DATA);
|
||||
ADSR <MOZZI_CONTROL_RATE, MOZZI_CONTROL_RATE> envelope;
|
||||
Smooth <long> aSmoothIntensity(0.95f);
|
||||
OverSample <unsigned int, 2> kOverSamplePitch;
|
||||
|
||||
//Global variables
|
||||
byte gain;
|
||||
bool MIDINotePlaying;
|
||||
bool gateIsHigh = false;
|
||||
float carrierFreq;
|
||||
long FMIntensity; // carries control info from updateControl to updateAudio
|
||||
|
||||
void MIDINoteOn(byte channel, byte note, byte velocity) {
|
||||
carrierFreq = mtof((int) note);
|
||||
envelope.noteOn();
|
||||
MIDINotePlaying = true;
|
||||
digitalWrite(LED, LOW);
|
||||
}
|
||||
|
||||
void MIDINoteOff(byte channel, byte note, byte velocity) {
|
||||
envelope.noteOff();
|
||||
digitalWrite(LED, HIGH);
|
||||
}
|
||||
|
||||
long softClip(long input) {
|
||||
int threshold = 2048;
|
||||
if (input < -threshold) {
|
||||
return -threshold + (input + threshold) / 4;
|
||||
} else if (input > threshold) {
|
||||
return threshold + (input - threshold) / 4;
|
||||
} else {
|
||||
return input;
|
||||
}
|
||||
}
|
||||
|
||||
void setup(){
|
||||
pinMode(LED, OUTPUT);
|
||||
pinMode(GateIn, INPUT_PULLUP);
|
||||
pinMode(EnvSwitch, INPUT_PULLUP);
|
||||
pinMode(DroneSwitch, INPUT_PULLUP);
|
||||
|
||||
MIDI.setHandleNoteOn(MIDINoteOn);
|
||||
MIDI.setHandleNoteOff(MIDINoteOff);
|
||||
MIDI.begin(MIDI_CHANNEL);
|
||||
|
||||
startMozzi();
|
||||
|
||||
envelope.setAttackLevel(255);
|
||||
|
||||
digitalWrite(LED, HIGH);
|
||||
}
|
||||
|
||||
void updateControl(){
|
||||
//Get Control Values
|
||||
int CVInVal = mozziAnalogRead(CVIn);
|
||||
int knob1Val = mozziAnalogRead(Knob1);
|
||||
int knob2Val = mozziAnalogRead(Knob2);
|
||||
int knob3Val = mozziAnalogRead(Knob3);
|
||||
int knob4Val = mozziAnalogRead(Knob4);
|
||||
int knobAVal = mozziAnalogRead(KnobA);
|
||||
int knobDRVal = mozziAnalogRead(KnobDR);
|
||||
int knobSVal = mozziAnalogRead(KnobS);
|
||||
bool droneSwitchVal = digitalRead(DroneSwitch);
|
||||
bool envSwitchVal = digitalRead(EnvSwitch);
|
||||
bool gateInVal = !digitalRead(GateIn);
|
||||
|
||||
//Remap the values and assign to parameter
|
||||
int intensity = kMapIntensity(knob1Val);
|
||||
int harmonics = kMapHarmonics(knob2Val);
|
||||
int LFOSpeed = kMapLFOSpeed(knob3Val);
|
||||
float expLFOSpeed = (float) LFOSpeed * LFOSpeed / 400000;
|
||||
float modSpeed = expLFOSpeed;
|
||||
|
||||
//Set pitch and play notes on trigger
|
||||
if (!MIDINotePlaying) {
|
||||
if (oversamplingEnabled) {
|
||||
int oversampledCVInVal = kOverSamplePitch.next(CVInVal);
|
||||
carrierFreq = mtof((float) kMapCarrierNote(oversampledCVInVal) / pitchSubSteps);
|
||||
} else {
|
||||
carrierFreq = mtof((float) kMapCarrierNote(CVInVal << 2) / pitchSubSteps);
|
||||
}
|
||||
digitalWrite(LED, !gateInVal);
|
||||
if (gateInVal && !gateIsHigh) {
|
||||
gateIsHigh = true;
|
||||
envelope.noteOn();
|
||||
} else if (!gateInVal && gateIsHigh) {
|
||||
gateIsHigh = false;
|
||||
envelope.noteOff();
|
||||
}
|
||||
} else if (MIDINotePlaying && !envelope.playing()) {
|
||||
MIDINotePlaying = false;
|
||||
}
|
||||
|
||||
//Update Envelope Settings
|
||||
int attackTime = kMapAttack(knobAVal);
|
||||
int decayReleaseTime = kMapDecayRelease(knobDRVal);
|
||||
int sustainLevel = kMapSustain(knobSVal);
|
||||
envelope.setDecayLevel(sustainLevel);
|
||||
envelope.setTimes(attackTime, decayReleaseTime, 30000, decayReleaseTime); //30000 is so the note will sustain 30 seconds unless a noteOff comes
|
||||
|
||||
//Calculate the modulation frequency
|
||||
int FMmodFreq = carrierFreq * harmonics;
|
||||
|
||||
//Set oscillator frequencies
|
||||
aCarrier.setFreq(carrierFreq);
|
||||
aModulator.setFreq(FMmodFreq);
|
||||
kSineLFO.setFreq(modSpeed);
|
||||
kSquareLFO.setFreq(modSpeed);
|
||||
kSawLFO.setFreq(modSpeed);
|
||||
kNoiseLFO.setFreq(modSpeed/4096);
|
||||
|
||||
envelope.update();
|
||||
|
||||
int sineLFOLevel;
|
||||
int squareLFOLevel;
|
||||
int sawLFOLevel;
|
||||
int noiseLFOLevel;
|
||||
if (knob4Val < 255) {
|
||||
sineLFOLevel = 255 - knob4Val;
|
||||
squareLFOLevel = knob4Val;
|
||||
sawLFOLevel = 0;
|
||||
noiseLFOLevel = 0;
|
||||
} else if (knob4Val < 511) {
|
||||
sineLFOLevel = 0;
|
||||
squareLFOLevel = 511 - knob4Val;
|
||||
sawLFOLevel = knob4Val - 255;
|
||||
noiseLFOLevel = 0;
|
||||
} else if (knob4Val < 767) {
|
||||
sineLFOLevel = 0;
|
||||
squareLFOLevel = 0;
|
||||
sawLFOLevel = 767 - knob4Val;
|
||||
noiseLFOLevel = knob4Val - 511;
|
||||
} else {
|
||||
sineLFOLevel = 0;
|
||||
squareLFOLevel = 0;
|
||||
sawLFOLevel = 0;
|
||||
noiseLFOLevel = 255;
|
||||
}
|
||||
|
||||
int shapedLFO = (kSineLFO.next() * sineLFOLevel +
|
||||
kSquareLFO.next() * squareLFOLevel +
|
||||
kSawLFO.next() * sawLFOLevel +
|
||||
kNoiseLFO.next() * noiseLFOLevel)>>8;
|
||||
|
||||
int env = envelope.next();
|
||||
int intensityEnv;
|
||||
if(envSwitchVal) {
|
||||
intensityEnv = env*3;
|
||||
} else {
|
||||
intensityEnv = 1;
|
||||
}
|
||||
FMIntensity = ((long)(intensity + intensityEnv) * (shapedLFO+128))>>8; //(shapedLFO+128))>>16; //(kSineLFO.next()+128))>>8;
|
||||
|
||||
if(!droneSwitchVal) {
|
||||
gain = env;
|
||||
} else {
|
||||
gain = 255;
|
||||
}
|
||||
|
||||
MIDI.read();
|
||||
}
|
||||
|
||||
AudioOutput updateAudio(){
|
||||
long modulation = aSmoothIntensity.next(FMIntensity) * aModulator.next();
|
||||
long signal = (aCarrier.phMod(modulation) * gain) >> 8; //envelope
|
||||
signal = softClip((signal * (127 + driveAmount)) >> 8); //overdrive
|
||||
return MonoOutput::from8Bit(signal);
|
||||
}
|
||||
|
||||
void loop(){
|
||||
audioHook();
|
||||
}
|
||||
Reference in New Issue
Block a user