Oleksiy/GravityFW
1
0
Fork 0
Code Issues Pull Requests Actions Packages Projects Releases Wiki Activity
Files
9840f23f77ce2d4e7efd877e699882926514522c
GravityFW/Software/Gravity/Gravity.ino

647 lines
19 KiB
C++
Raw Blame History

#include <Wire.h>
#include <RotaryEncoder.h>
#include <FlexiTimer2.h>
#include <EEPROM.h>
#include <U8g2lib.h>
#include <avr/wdt.h>
#include <NeoHWSerial.h>
#include "config.h"
#include "fonts.h"
#define VERSION "V:1.2A2"
byte memCode = 'e'; //Change to different letter if you changed the data structure
uint16_t CV1Calibration = 512;
uint16_t CV2Calibration = 512;
bool showDone = false;
const int subDivs[] = { -24, -12, -8, -6, -4, -3, -2, 1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11, 12, 16, 24, 32, 64, 128 }; //positive - divide, negative - multiply, 0 - off
byte bpm = 130;
byte bpmModulationChannel = 200; //0 - CV1, 1 - CV2, 255 - OFF
byte bpmModulationRange = 0;
struct channel {
byte mode : 3; //mv: 7. 0 - CLK, 1 - RND, 2 - SEQ, 3 - SWING, 4 - Gate
byte subDiv : 5; //mv: 32
byte random : 4; //mv: 16
byte seqPattern : 4;
byte CV1Target : 3; //0 - Off, 1 - Subdiv, 2 - RND, 3 - SeqPattern
byte CV2Target : 3;
uint8_t swing : 3;
uint8_t offset : 7; //mv: 128
uint8_t gate : 7;
bool isMute : 1;
};
channel channels[7] = { //array of channel settings
{ 0, 7, 0, 0, 0, 0, 0, 0, 1, 0 },
{ 0, 7, 0, 0, 0, 0, 0, 0, 1, 0 },
{ 0, 7, 0, 0, 0, 0, 0, 0, 1, 0 },
{ 0, 7, 0, 0, 0, 0, 0, 0, 1, 0 },
{ 0, 7, 0, 0, 0, 0, 0, 0, 1, 0 },
{ 0, 7, 0, 0, 0, 0, 0, 0, 1, 0 },
{ 0, 7, 0, 0, 0, 0, 0, 0, 1, 0 }
};
bool seqA1[16] = {1, 0, 0, 0, 1, 0, 0, 0, 1, 0, 0, 0, 1, 0, 0, 1}; //switch to struct seqs { uint32_t sequence; uint8_t length : 5 ; uint8_t currentStep : 5}. test with lengthOf
bool seqA2[16] = {0, 0, 0, 0, 1, 0, 0, 0, 0, 0, 0, 1, 0, 0, 0, 0};
bool seqA3[16] = {1, 0, 0, 1, 0, 0, 1, 0, 0, 1, 0, 0, 1, 0, 0, 0};
bool seqA4[16] = {0, 0, 1, 1, 0, 0, 1, 1, 0, 0, 1, 1, 0, 0, 1, 1};
bool seqA5[16] = {0, 1, 1, 1, 0, 1, 1, 1, 0, 1, 1, 1, 0, 1, 1, 1};
bool seqA6[16] = {0, 0, 1, 0, 1, 0, 1, 0, 0, 0, 1, 0, 1, 0, 1, 0};
bool seqA7[16] = {1, 1, 1, 1, 1, 1, 0, 1, 1, 1, 1, 1, 1, 1, 1, 0};
bool seqA8[16] = {1, 1, 0, 0, 1, 1, 0, 0, 1, 1, 1, 0, 1, 1, 0, 1};
bool seqB1[16] = {0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0};
bool seqB2[16] = {0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0};
bool seqB3[16] = {0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0};
bool seqB4[16] = {0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0};
bool seqB5[16] = {0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0};
bool seqB6[16] = {0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0};
bool seqB7[16] = {0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0};
bool seqB8[16] = {0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0, 0};
byte currentStep = 0;
byte stepNumSelected = 0;
bool *patternToEdit;
unsigned int channelPulseCount[7];
unsigned int channelPulsesPerCycle[7];
byte sixteenthPulseCount = 0;
int playingModes[7]; // should be renamed to currentSubdivs or something. Updated from channels object on beat and with applied CV modulation
int playingModesOld[7];
unsigned int pulsePeriod;
bool isPlaying;// = false; // replace to something like byte status where 1xxxxxx isPlaying, x1xxxxx isRecording etc
bool isRecording = false;
bool recordToNextStep = false;
bool MIDIClockReceived = false;
unsigned int tickCount = 0;
unsigned int pulseCount = 0;
byte masterClockMode = 0; // 0 - internal, 1 - external 24ppqn, 2 - MIDI
byte extClockPPQN = 0; // 0 - 24, 1 - 4 (1/16)
byte extraChannel = 0; // 0 - off, 1 - pulse out = 7th channel
unsigned long lastExtPulseTime = 0;
unsigned long newExtPulseTime = 0;
bool needPulseReset[] = { true, true, true, true, true, true, true };
uint16_t gateLengthTime[] = {120, 120, 120, 120, 120, 120, 120};
uint16_t gateCountDown[7];
bool stepIsOdd = 1;
byte displayTab = 0;
bool insideTab = false;
byte menuItem = 0;
bool menuItemSelected = false;
byte lastMenuItem = 3;
byte displayScreen = 0; //0 - main, 1 - sequencer, 2 - settings
bool playBtnPushed = false;
bool shiftBtnPushed = false;
int CV1Input = 0;
int CV2Input = 0;
int encPositionOld = 0;
int encDirectionOld = 0;
unsigned long encPressedTime;
unsigned long encReleasedTime;
unsigned long playPressedTime;
unsigned long playReleasedTime;
unsigned long shiftPressedTime;
unsigned long shiftReleasedTime;
bool encBtnPushed;
int extResetCountdown;
int extTriggerCount;
//unsigned long lastInteractionTime; // used for display timeout
U8G2_SSD1306_128X64_NONAME_2_HW_I2C u8g2(U8G2_R2, SCL, SDA, U8X8_PIN_NONE);
RotaryEncoder encoder(ENC_D1_PIN, ENC_D2_PIN, RotaryEncoder::LatchMode::TWO03);
String version;
void setup() {
version = F(VERSION);
NeoSerial.begin(31250);
NeoSerial.attachInterrupt(receiveMIDI);
pinMode(ENC_BTN_PIN, INPUT_PULLUP);
pinMode(START_STOP_BTN_PIN, INPUT_PULLUP);
pinMode(SHIFT_BTN_PIN, INPUT_PULLUP);
pinMode(EXT_INPUT_PIN, INPUT_PULLUP);
attachInterrupt(digitalPinToInterrupt(EXT_INPUT_PIN), externalClock, FALLING);
for (byte i = 0; i < 6; i++) {
pinMode(outsPins[i], OUTPUT);
}
pinMode(clockOutPin, OUTPUT);
loadState();
u8g2.begin();
checkScreenRotation();
updateScreen();
calculateCycles();
calculateBPMTiming();
resetClocks();
FlexiTimer2::set(1, 1.0 / 10000, clock); // 1.0/1000 = 1ms period. If other than 1ms calculateBPMTiming() might need tweaking
FlexiTimer2::start();
}
void loop() {
if (masterClockMode == 1 && extClockPPQN == 1) {
calculateBPMTiming();
}
checkInputs();
}
void sendMIDIClock() {
NeoSerial.write(0xF8);
}
void sendMIDIStart() {
NeoSerial.write(0xFA);
}
void sendMIDIStop() {
NeoSerial.write(0xFC);
}
void receiveMIDI( uint8_t msg, uint8_t status ) {
if (masterClockMode == 2) {
if (msg == 0xF8) { //Clock
MIDIClockReceived = true;
} else if (msg == 0xFC) { //stop
isPlaying = false;
} else if (msg == 0xFA || msg == 0xFB) { //start and continue
isPlaying = true;
}
}
}
void clock() {
if (isPlaying) {
// Action on each pulse
if (tickCount == 0) {
sendTriggers();
if (!extraChannel) {
digitalWrite(clockOutPin, HIGH);
}
sendMIDIClock();
}
//this part gets the Pulse and Ticks ticking
//it's placed after the triggers to avoid problems on the start (when pulseCount==0)
tickCount++;
if (masterClockMode == 0) {
if (tickCount >= pulsePeriod) {
tickCount = 0;
if (pulseCount < (PPQN - 1)) { //-1 is here to avoid extra IF to reset to 0
pulseCount++;
} else {
pulseCount = 0;
}
if (bpmModulationRange != 0) {
calculateBPMTiming();
}
}
}
if (masterClockMode == 1 && extClockPPQN == 1) {
if (tickCount >= pulsePeriod && pulseCount < (PPQN - 1)) { // ((6 * (extTriggerCount + 1)) - 1)) { //this formula puts it out of sync, so there's PPQN-1 for now
tickCount = 0;
pulseCount++;
}
}
if (masterClockMode == 2 && MIDIClockReceived) { // MIDI should happen here (needs testing)
tickCount = 0; //to make things happen in the main clock function
if (pulseCount < (PPQN - 1)) {
pulseCount++;
} else {
pulseCount = 0;
}
MIDIClockReceived = false;
}
// pull low all outputs after set pulse length
for (byte i = 0; i < 7; i++) {
if (channels[i].mode != 4 && tickCount >= PULSE_LENGTH) { //everything but gate mode
digitalWrite(outsPins[i], LOW);
} else if (channels[i].mode == 4 && tickCount >= gateCountDown[i]) { //gate mode gateLengthTime[i] < pulsePeriod
digitalWrite(outsPins[i], LOW);
gateCountDown[i] = gateLengthTime[i];
} else if (channels[i].mode == 4 && gateCountDown[i] > pulsePeriod && tickCount == 0) {
gateCountDown[i] = gateCountDown[i] - pulsePeriod;
}
}
}
}
void externalClock() {
lastExtPulseTime = newExtPulseTime;
newExtPulseTime = millis();
if (masterClockMode == 1 && extClockPPQN == 0) { // EXT 24ppqn
if (!isPlaying) {
isPlaying = true;
}
//reset cycles if there were no pulses for a while
if ((newExtPulseTime - lastExtPulseTime) > 125) { //125ms is 20bpm
resetClocks();
}
tickCount = 0; //to make things happen in the main clock function
if (pulseCount < (PPQN - 1)) {
pulseCount++;
} else {
pulseCount = 0;
}
} else if (masterClockMode == 1 && extClockPPQN == 1) { //EXT 1/16
if (!isPlaying) {
isPlaying = true;
}
if ((newExtPulseTime - lastExtPulseTime) > 750) {
resetClocks();
extResetCountdown = 0;
extTriggerCount = 0;
}
if (extTriggerCount == 0) { //happens on beat
pulseCount = 0;
tickCount = 0;
}
if (extTriggerCount < 3) {
extTriggerCount++;
} else {
extTriggerCount = 0;
}
if (extResetCountdown < 4) { //reset on the second beat (5th pulse), so that BPM is already calculated correctly
extResetCountdown++;
} else if (extResetCountdown == 4) {
resetClocks();
extResetCountdown++; //to get out of the loop
}
}
}
void sendTriggers() { //rename to onPulse or something
for (byte i = 0; i < (extraChannel ? 7 : 6); i++) {
if (playingModes[i] != subDivs[channels[i].subDiv] && playingModesOld[i] != playingModes[i]) {
needPulseReset[i] = true;
playingModesOld[i] = playingModes[i];
}
}
//16th notes for sequencer and swing
if (sixteenthPulseCount == 0) {
bool *currentSeq;
stepIsOdd = !stepIsOdd;
for (byte i = 0; i < (extraChannel ? 7 : 6); i++) {
//pattern modulation
int seqMod = 0;
byte seqPattern;
if (channels[i].CV2Target == 3) {
seqMod = map(CV2Input, -1, 1024, -8, 8); //-1 and 1024 are to try to make the last step not at max value (should make the range from -7 to +7)
} else if (channels[i].CV1Target == 3) {
seqMod = map(CV1Input, -1, 1024, -8, 8);
}
if (channels[i].seqPattern < 8 && channels[i].seqPattern + seqMod >= 8) {
seqPattern = 7;
} else if (channels[i].seqPattern < 8 && channels[i].seqPattern + seqMod < 0) {
seqPattern = 0;
} else if (channels[i].seqPattern >= 8 && channels[i].seqPattern + seqMod < 8) {
seqPattern = 8;
} else if (channels[i].seqPattern >= 8 && channels[i].seqPattern + seqMod >= 16) {
seqPattern = 15;
} else {
seqPattern = channels[i].seqPattern + seqMod;
}
if (seqPattern == 0) {
currentSeq = seqA1;
} else if (seqPattern == 1) {
currentSeq = seqA2;
} else if (seqPattern == 2) {
currentSeq = seqA3;
} else if (seqPattern == 3) {
currentSeq = seqA4;
} else if (seqPattern == 4) {
currentSeq = seqA5;
} else if (seqPattern == 5) {
currentSeq = seqA6;
} else if (seqPattern == 6) {
currentSeq = seqA7;
} else if (seqPattern == 7) {
currentSeq = seqA8;
} else if (seqPattern == 8) {
currentSeq = seqB1;
} else if (seqPattern == 9) {
currentSeq = seqB2;
} else if (seqPattern== 10) {
currentSeq = seqB3;
} else if (seqPattern == 11) {
currentSeq = seqB4;
} else if (seqPattern == 12) {
currentSeq = seqB5;
} else if (seqPattern == 13) {
currentSeq = seqB6;
} else if (seqPattern == 14) {
currentSeq = seqB7;
} else if (seqPattern == 15) {
currentSeq = seqB8;
}
if (channels[i].mode == 2 && currentSeq[currentStep]) {
digitalWrite(outsPins[i], HIGH);
}
}
}
if (sixteenthPulseCount < (PPQN / 4) - 1) {
sixteenthPulseCount++;
if (sixteenthPulseCount > 3) { //quantization. might need fine-tuning
recordToNextStep = true;
}
} else {
sixteenthPulseCount = 0;
if (currentStep < 15) {
currentStep ++;
} else {
currentStep = 0;
}
recordToNextStep = false;
}
//switching modes on the beat and resetting channel clock
if (pulseCount == 0) {
calculateCycles();
for (byte i = 0; i < (extraChannel ? 7 : 6); i++) {
if (needPulseReset[i] == true) {
channelPulseCount[i] = 0;
needPulseReset[i] = false;
}
}
}
//multiplier
for (byte i = 0; i < (extraChannel ? 7 : 6); i++) {
//RND modulation
byte randMod = 0;
if (channels[i].CV1Target == 2) {
randMod = randMod + CV1Input;
}
if (channels[i].CV2Target == 2) {
randMod = randMod + CV2Input;
}
if (channels[i].CV1Target == 2 || channels[i].CV2Target == 2) {
randMod = map(randMod, 0, 1023, -5, +5);
}
byte randAmount = channels[i].random + randMod;
if (randAmount > 100) {
randAmount = 0;
} else if (randAmount > 10) {
randAmount = 10;
}
if (!channels[i].isMute) {
if ((channels[i].mode == 3 && channelPulseCount[i] == 0 && stepIsOdd == 0)
|| (channels[i].mode == 3 && channelPulseCount[i] == channels[i].swing && stepIsOdd == 1) //swing
) {
digitalWrite(outsPins[i], HIGH);
}
if ((channels[i].mode == 0 && channelPulseCount[i] == channels[i].offset) //CLK with offset
|| (channels[i].mode == 1 && channelPulseCount[i] == 0 && (random(10) + 1) > randAmount) //RND
|| (channels[i].mode == 4 && channelPulseCount[i] == 0) //Gate
) {
digitalWrite(outsPins[i], HIGH);
}
}
if (channelPulseCount[i] < channelPulsesPerCycle[i]) {
channelPulseCount[i]++;
} else {
channelPulseCount[i] = 0;
}
}
}
void calculateCycles() {
for (byte i = 0; i < (extraChannel ? 7 : 6); i++) {
int mod = 0; //subdiv modulation happens here
if (channels[i].CV1Target == 1) {
mod = map(CV1Input, -1, 1024, -5, 5);
} else if (channels[i].CV2Target == 1) {
mod = map(CV2Input, -1, 1024, -5, 5);
}
playingModes[i] = subDivs[channels[i].subDiv - mod]; //subtracting because the innitial array is backwards
if (channels[i].mode == 2 || channels[i].mode == 3) { //Sequencer and swing plays 1/16th
channelPulsesPerCycle[i] = (PPQN / 4) - 1;
} else if (playingModes[i] > 0) {
channelPulsesPerCycle[i] = (playingModes[i] * PPQN) - 1;
} else if (playingModes[i] < 0) {
channelPulsesPerCycle[i] = (PPQN / abs(playingModes[i])) - 1;
}
if (channels[i].mode == 4) {
calculateGate(i);
}
}
}
void calculateGate(uint8_t channel) {
//if (subDivs[channels[channel].subDiv] > 0) {
gateLengthTime[channel] = (channelPulsesPerCycle[channel] * pulsePeriod / 100) * channels[channel].gate;
gateCountDown[channel] = gateLengthTime[channel];
//}
}
void calculateBPMTiming() {
int mod = 0;
if (masterClockMode == 0) { //Internal clock
if (bpmModulationRange != 0 && bpmModulationChannel == 0) {
mod = map(CV1Input, 0, 1023, bpmModulationRange * -10, bpmModulationRange * 10);
} else if (bpmModulationRange != 0 && bpmModulationChannel == 1) {
mod = map(CV2Input, 0, 1023, bpmModulationRange * -10, bpmModulationRange * 10);
}
byte calcbpm = bpm + mod;
if (calcbpm > MAXBPM) { calcbpm = MAXBPM; };
pulsePeriod = 600000 / (calcbpm * PPQN);
} else if (masterClockMode == 1 && extClockPPQN == 1) { //for ext 1/16 clock
pulsePeriod = (newExtPulseTime - lastExtPulseTime) * 10 / 6;
}
for (byte i = 0; i < (extraChannel ? 7 : 6); i++) {
if (channels[i].mode == 4) {
calculateGate(i);
}
}
}
void resetClocks() {
for (byte i = 0; i < (extraChannel ? 7 : 6); i++) {
channelPulseCount[i] = 0;
digitalWrite(outsPins[i], LOW); //to avoid stuck leds
}
pulseCount = 0;
tickCount = 0;
sixteenthPulseCount = 0;
currentStep = 0;
stepIsOdd = 1;
}
void saveState() {
int addr = 0;
EEPROM.put(addr, bpm);
addr = addr + sizeof(bpm);
EEPROM.put(addr, bpmModulationChannel);
addr = addr + sizeof(bpmModulationChannel);
EEPROM.put(addr, bpmModulationRange);
addr = addr + sizeof(bpmModulationRange);
EEPROM.put(addr, masterClockMode);
addr = addr + sizeof(masterClockMode);
EEPROM.put(addr, channels);
addr = addr + sizeof(channels);
EEPROM.put(addr, seqA1);
addr = addr + sizeof(seqA1);
EEPROM.put(addr, seqA2);
addr = addr + sizeof(seqA2);
EEPROM.put(addr, seqA3);
addr = addr + sizeof(seqA3);
EEPROM.put(addr, seqA4);
addr = addr + sizeof(seqA4);
EEPROM.put(addr, seqA5);
addr = addr + sizeof(seqA5);
EEPROM.put(addr, seqA6);
addr = addr + sizeof(seqA6);
EEPROM.put(addr, seqA7);
addr = addr + sizeof(seqA7);
EEPROM.put(addr, seqA8);
addr = addr + sizeof(seqA8);
EEPROM.put(addr, seqB1);
addr = addr + sizeof(seqB1);
EEPROM.put(addr, seqB2);
addr = addr + sizeof(seqB2);
EEPROM.put(addr, seqB3);
addr = addr + sizeof(seqB3);
EEPROM.put(addr, seqB4);
addr = addr + sizeof(seqB4);
EEPROM.put(addr, seqB5);
addr = addr + sizeof(seqB5);
EEPROM.put(addr, seqB6);
addr = addr + sizeof(seqB6);
EEPROM.put(addr, seqB7);
addr = addr + sizeof(seqB7);
EEPROM.put(addr, seqB8);
addr = addr + sizeof(seqB8);
EEPROM.put(addr, CV1Calibration);
addr = addr + sizeof(CV1Calibration);
EEPROM.put(addr, CV2Calibration);
addr = addr + sizeof(CV2Calibration);
EEPROM.put(addr, rotateScreen);
addr = addr + sizeof(rotateScreen);
EEPROM.put(addr, extClockPPQN);
addr = addr + sizeof(extClockPPQN);
EEPROM.put(addr, reverseEnc);
addr = addr + sizeof(reverseEnc);
EEPROM.put(addr, extraChannel);
}
void loadState() {
//check last bit in eeprom to know if the correct settings were stored
if (EEPROM.read(1023) == memCode) {
int addr = 0;
EEPROM.get(addr, bpm);
addr = addr + sizeof(bpm);
EEPROM.get(addr, bpmModulationChannel);
addr = addr + sizeof(bpmModulationChannel);
EEPROM.get(addr, bpmModulationRange);
addr = addr + sizeof(bpmModulationRange);
EEPROM.get(addr, masterClockMode);
addr = addr + sizeof(masterClockMode);
EEPROM.get(addr, channels);
addr = addr + sizeof(channels);
EEPROM.get(addr, seqA1);
addr = addr + sizeof(seqA1);
EEPROM.get(addr, seqA2);
addr = addr + sizeof(seqA2);
EEPROM.get(addr, seqA3);
addr = addr + sizeof(seqA3);
EEPROM.get(addr, seqA4);
addr = addr + sizeof(seqA4);
EEPROM.get(addr, seqA5);
addr = addr + sizeof(seqA5);
EEPROM.get(addr, seqA6);
addr = addr + sizeof(seqA6);
EEPROM.get(addr, seqA7);
addr = addr + sizeof(seqA7);
EEPROM.get(addr, seqA8);
addr = addr + sizeof(seqA8);
EEPROM.get(addr, seqB1);
addr = addr + sizeof(seqB1);
EEPROM.get(addr, seqB2);
addr = addr + sizeof(seqB2);
EEPROM.get(addr, seqB3);
addr = addr + sizeof(seqB3);
EEPROM.get(addr, seqB4);
addr = addr + sizeof(seqB4);
EEPROM.get(addr, seqB5);
addr = addr + sizeof(seqB5);
EEPROM.get(addr, seqB6);
addr = addr + sizeof(seqB6);
EEPROM.get(addr, seqB7);
addr = addr + sizeof(seqB7);
EEPROM.get(addr, seqB8);
addr = addr + sizeof(seqB8);
EEPROM.get(addr, CV1Calibration);
addr = addr + sizeof(CV1Calibration);
EEPROM.get(addr, CV2Calibration);
addr = addr + sizeof(CV2Calibration);
EEPROM.get(addr, rotateScreen);
addr = addr + sizeof(rotateScreen);
EEPROM.get(addr, extClockPPQN);
addr = addr + sizeof(extClockPPQN);
EEPROM.get(addr, reverseEnc);
addr = addr + sizeof(reverseEnc);
EEPROM.get(addr, extraChannel);
} else {
saveState(); //write default values to EEPROM
EEPROM.write(1023, memCode);
}
}
void reboot() {
wdt_enable(WDTO_15MS); //reboot after 15ms
while(true);
}
void calibrateCVs() {
CV1Calibration = analogRead(ANALOGUE_INPUT_1_PIN);
CV2Calibration = analogRead(ANALOGUE_INPUT_2_PIN);
saveState();
showDone = true;
updateScreen();
}
void checkScreenRotation() {
if (rotateScreen) {
u8g2.setDisplayRotation(U8G2_R0);
} else {
u8g2.setDisplayRotation(U8G2_R2);
}
}
Reference in New Issue View Git Blame Copy Permalink